/************************************************************************************/
/*  Program name CAPFNDEXT_CONC_PROG_PARAM.sql                                      */
/*  Creater:  WONG Wing Kin (PCCW - UniHub)                                         */
/*************   History   *************************                                */
/* 30 NOV, 2005   WONG Wing Kin         First created                               */
/************************************************************************************/
ALTER SESSION SET NLS_DATE_FORMAT='YYYYMMDD HH24:MI:SS';
SET SERVEROUTPUT ON SIZE 1000000;
SET VERIFY OFF

DECLARE
	lv_Prog_ID		VARCHAR2(100)	:=	'CAPFNDEXT_CONC_PROG_PARAM';

	lv_Scc_Count	NUMBER			:=	0;
	lv_Err_Count	NUMBER			:=	0;
	lv_Err_Msg		VARCHAR2(500)	:=	'No Error';

	lv_FileName		VARCHAR2(100)	:=	'CAPFND_CONC_PROG_PARAM.dat';
	lv_PathName		VARCHAR2(100)	:=	'/tmp';
	lv_UTL_File		UTL_FILE.File_Type;

	lv_NGO			VARCHAR2(100);
	lv_NGO_Count	NUMBER;

	CURSOR Cur_F(p_NGO VARCHAR2) IS
	SELECT
		FDFCU.*
	FROM
		FND_CONCURRENT_PROGRAMS			FCP,
		FND_CONCURRENT_PROGRAMS_TL		FCPT,
		FND_DESCR_FLEX_COLUMN_USAGES	FDFCU
	WHERE	FCP.Application_ID						=	FCPT.Application_ID
	AND		FCP.Concurrent_Program_ID				=	FCPT.Concurrent_Program_ID
	AND		FCPT.Language							=	'US'
	AND		SUBSTR(FCPT.User_Concurrent_Program_Name,1,4)	=	p_NGO
	AND		FCP.Application_ID						=	FDFCU.Application_ID
	AND		'$SRS$.'||FCP.Concurrent_Program_Name	=	FDFCU.Descriptive_Flexfield_Name
	ORDER BY
		FCP.Application_ID,
		FCP.Concurrent_Program_Name,
		FDFCU.Column_Seq_Num;

BEGIN
	lv_NGO			:=	UPPER('&1');

	SELECT	COUNT('A')
	INTO	lv_NGO_Count
	FROM	HR_ALL_ORGANIZATION_UNITS
	WHERE	SUBSTR(Name,4,4)	=	lv_NGO;

	IF	lv_NGO_Count	>=	1	THEN
		lv_UTL_File		:=	UTL_FILE.FOpen(lv_PathName, lv_FileName, 'w', 32767);
		FOR C1 IN Cur_F(lv_NGO) LOOP
			UTL_FILE.PUT_LINE(
				lv_UTL_File,
				C1.Application_ID||CHR(9)||
				C1.Descriptive_Flexfield_Name||CHR(9)||
				C1.Descriptive_Flex_Context_Code||CHR(9)||
				C1.Application_Column_Name||CHR(9)||
				C1.End_User_Column_Name||CHR(9)||
				C1.Last_Update_Date||CHR(9)||
					C1.Last_Updated_By||CHR(9)||
				C1.Creation_Date||CHR(9)||
					C1.Created_By||CHR(9)||
				C1.Last_Update_Login||CHR(9)||
				C1.Column_Seq_Num||CHR(9)||
				C1.Enabled_Flag||CHR(9)||
				C1.Required_Flag||CHR(9)||
				C1.Security_Enabled_Flag||CHR(9)||
				C1.Display_Flag||CHR(9)||
				C1.Display_Size||CHR(9)||
				C1.Maximum_Description_Len||CHR(9)||
				C1.Concatenation_Description_Len||CHR(9)||
					C1.Flex_Value_Set_ID||CHR(9)||
				C1.Range_Code||CHR(9)||
				C1.Default_Type||CHR(9)||
				REPLACE(REPLACE(C1.Default_Value,CHR(10),'^C10^'),CHR(13),'^C10^')||CHR(9)||
				C1.SRW_Param||CHR(9)||
				C1.Runtime_Property_Function||CHR(9)||
				CAPBREXT_COMMON.GetUser(C1.LAST_UPDATED_BY)||CHR(9)||
				CAPBREXT_COMMON.GetUser(C1.CREATED_BY)||CHR(9)||
				CAPBREXT_COMMON.GetParentValueSet(C1.Flex_Value_Set_ID)
			);
			lv_Scc_Count	:=	lv_Scc_Count	+	1;
		END LOOP;
		UTL_FILE.FClose(lv_UTL_File);
		IF	lv_Scc_Count	=	0	THEN
			lv_Err_Msg	:=	lv_NGO||': No Concurrent Program Parameter for this NGO';
		END IF;
	ELSE
		lv_Err_Count	:=	lv_Err_Count + 1;
		lv_Err_Msg		:=	lv_NGO||': No such NGO exists';
	END IF;

	INSERT INTO CAPCNV_LOG(
		PROG_ID,
		PROCESS_DATE,
		RECORD_PROCESSED,
		RECORD_REJECTED,
		RECORD_EXTRACTED,
		ERR_MSG
	) VALUES (
		lv_Prog_ID,
		SYSDATE,
		lv_Scc_Count,
		lv_Err_Count,
		lv_Scc_Count-lv_Err_Count,
		lv_Err_Msg
	);

	COMMIT;
END;
/