/************************************************************************************/
/*  Program name CAPFNDEXT_REQ_SET_PGRM.sql                                         */
/*  Creater:  Chan Billy Ka Keung (PCCW - UniHub)                                   */
/*************   History   *************************                                */
/* 27 JAN, 2005   CHAN Billy Ka Keung         First created                         */
/************************************************************************************/
ALTER SESSION SET NLS_DATE_FORMAT='YYYYMMDD HH24:MI:SS';
SET SERVEROUTPUT ON SIZE 1000000;
SET VERIFY OFF

DECLARE
	lv_Prog_ID				VARCHAR2(100)	:=	'CAPFNDEXT_REQ_SET_PGRM';

	lv_FileName				VARCHAR2(100)	:=	'CAPFND_REQ_SET_PGRM.dat';
	lv_PathName				VARCHAR2(100)	:=	'/tmp';
	lv_UTL_File				UTL_FILE.FILE_TYPE;

	lv_Scc_Count			NUMBER			:=	0;
	lv_Err_Count			NUMBER			:=	0;
	lv_Err_Msg				VARCHAR2(500)	:=	'No Error';

	lv_NGO_Name				VARCHAR2(100);
	lv_NGO_Count			NUMBER;

	CURSOR Cur_F(p_NGO VARCHAR2) IS
	SELECT
		L.*
	FROM
		FND_REQUEST_SETS_TL					A,
		FND_REQUEST_SET_PROGRAMS			L
	WHERE	UPPER(SUBSTR(A.DESCRIPTION,1,4))	=	p_NGO
	AND		A.REQUEST_SET_ID = L.REQUEST_SET_ID
	AND		A.APPLICATION_ID = L.SET_APPLICATION_ID
	AND		A.LANGUAGE = 'US';

BEGIN
	lv_NGO_Name		:=	UPPER('&1');

	SELECT	COUNT('A')
	INTO	lv_NGO_Count
	FROM	HR_ALL_ORGANIZATION_UNITS
	WHERE	SUBSTR(Name,4,4)	=	lv_NGO_Name;

	IF	lv_NGO_Count	>=	1 THEN
		lv_UTL_File		:=	UTL_FILE.FOpen(lv_PathName, lv_FileName, 'w');
		FOR C1 IN Cur_F(lv_NGO_Name) LOOP
			UTL_FILE.PUT_LINE(
				lv_UTL_File,
				C1.SET_APPLICATION_ID||CHR(9)||
				C1.REQUEST_SET_ID||CHR(9)||
				C1.REQUEST_SET_STAGE_ID||CHR(9)||
				C1.REQUEST_SET_PROGRAM_ID||CHR(9)||
				C1.SEQUENCE||CHR(9)||
				C1.LAST_UPDATE_DATE||CHR(9)||
					C1.LAST_UPDATED_BY||CHR(9)||
				C1.CREATION_DATE||CHR(9)||
					C1.CREATED_BY||CHR(9)||
				C1.LAST_UPDATE_LOGIN||CHR(9)||
				C1.PROGRAM_APPLICATION_ID||CHR(9)||
					C1.CONCURRENT_PROGRAM_ID||CHR(9)||
				C1.NLS_LANGUAGE||CHR(9)||
				C1.NLS_TERRITORY||CHR(9)||
				C1.CRITICAL||CHR(9)||
				C1.NUMBER_OF_COPIES||CHR(9)||
				C1.PRINTER||CHR(9)||
				C1.PRINT_STYLE||CHR(9)||
				C1.SAVE_OUTPUT_FLAG||CHR(9)||
				CAPBREXT_COMMON.GetUser(C1.LAST_UPDATED_BY)||CHR(9)||
				CAPBREXT_COMMON.GetUser(C1.CREATED_BY)||CHR(9)||
				CAPBREXT_COMMON.GetFNDConcPrgName(C1.CONCURRENT_PROGRAM_ID)
			);
			lv_Scc_Count	:=	lv_Scc_Count	+	1;
		END LOOP;
		UTL_FILE.FClose(lv_UTL_File);
		IF	lv_Scc_Count	=	0	THEN
			lv_Err_Msg	:=	lv_NGO_Name||': No request sets for this business group';
		END IF;
	ELSE
		lv_Err_Count	:=	lv_Err_Count + 1;
		lv_Err_Msg		:=	lv_NGO_Name||': No such NGO exists';
	END IF;

	INSERT INTO CAPCNV_LOG(
		PROG_ID,
		PROCESS_DATE,
		RECORD_PROCESSED,
		RECORD_REJECTED,
		RECORD_EXTRACTED,
		ERR_MSG
	) VALUES (
		lv_Prog_ID,
		SYSDATE,
		lv_Scc_Count,
		lv_Err_Count,
		lv_Scc_Count-lv_Err_Count,
		lv_Err_Msg
	);

	COMMIT;
END;
/
