/************************************************************************************/
/*  Program name CAPFNDEXT_CONC_PROG_CONTEXT_TL.sql                                 */
/*  Creater:  WONG Wing Kin (PCCW - UniHub)                                         */
/*************   History   *************************                                */
/* 30 NOV, 2005   WONG Wing Kin         First created                               */
/************************************************************************************/
ALTER SESSION SET NLS_DATE_FORMAT='YYYYMMDD HH24:MI:SS';
SET SERVEROUTPUT ON SIZE 1000000;
SET VERIFY OFF

DECLARE
	lv_Prog_ID		VARCHAR2(100)	:=	'CAPFNDEXT_CONC_PROG_CONTEXT_TL';

	lv_Scc_Count	NUMBER			:=	0;
	lv_Err_Count	NUMBER			:=	0;
	lv_Err_Msg		VARCHAR2(500)	:=	'No Error';

	lv_FileName		VARCHAR2(100)	:=	'CAPFND_CONC_PROG_CONTEXT_TL.dat';
	lv_PathName		VARCHAR2(100)	:=	'/tmp';
	lv_UTL_File		UTL_FILE.File_Type;

	lv_NGO			VARCHAR2(100);
	lv_NGO_Count	NUMBER;

	CURSOR Cur_F(p_NGO VARCHAR2) IS
	SELECT
		FDFCT.*
	FROM
		FND_CONCURRENT_PROGRAMS		FCP,
		FND_CONCURRENT_PROGRAMS_TL	FCPT,
		FND_DESCR_FLEX_CONTEXTS_TL	FDFCT
	WHERE	FCP.Application_ID					=	FCPT.Application_ID
	AND		FCP.Concurrent_Program_ID			=	FCPT.Concurrent_Program_ID
	AND		FCPT.Language						=	'US'
	AND		SUBSTR(FCPT.User_Concurrent_Program_Name,1,4)	=	p_NGO
	AND		FDFCT.Descriptive_Flexfield_Name	=	'$SRS$.'||FCP.Concurrent_Program_Name
	AND		FDFCT.Application_ID				=	FCP.Application_ID
	ORDER BY
		FDFCT.Application_ID,
		FDFCT.Descriptive_Flexfield_Name,
		FDFCT.Language;

BEGIN
	lv_NGO			:=	UPPER('&1');

	SELECT	COUNT('A')
	INTO	lv_NGO_Count
	FROM	HR_ALL_ORGANIZATION_UNITS
	WHERE	SUBSTR(Name,4,4)	=	lv_NGO;

	IF	lv_NGO_Count	>=	1	THEN
		lv_UTL_File		:=	UTL_FILE.FOpen(lv_PathName, lv_FileName, 'w');
		FOR C1 IN Cur_F(lv_NGO) LOOP
			UTL_FILE.PUT_LINE(
				lv_UTL_File,
				C1.Application_ID||CHR(9)||
				C1.Descriptive_Flexfield_Name||CHR(9)||
				C1.Descriptive_Flex_Context_Code||CHR(9)||
				C1.Language||CHR(9)||
				C1.Last_Update_Date||CHR(9)||
				C1.Last_Updated_By||CHR(9)||
				C1.Creation_Date||CHR(9)||
				C1.Created_By||CHR(9)||
				C1.Last_Update_Login||CHR(9)||
				C1.Description||CHR(9)||
				C1.Descriptive_Flex_Context_Name||CHR(9)||
				C1.Source_Lang||CHR(9)||
				CAPBREXT_COMMON.GetUser(C1.Last_Updated_By)||CHR(9)||
				CAPBREXT_COMMON.GetUser(C1.Created_By)
			);
			lv_Scc_Count	:=	lv_Scc_Count	+	1;
		END LOOP;
		UTL_FILE.FClose(lv_UTL_File);
		IF	lv_Scc_Count	=	0	THEN
			lv_Err_Msg	:=	lv_NGO||': No Concurrent Program Flex Cont TL for this NGO';
		END IF;
	ELSE
		lv_Err_Count	:=	lv_Err_Count + 1;
		lv_Err_Msg		:=	lv_NGO||': No such NGO exists';
	END IF;

	INSERT INTO CAPCNV_LOG(
		PROG_ID,
		PROCESS_DATE,
		RECORD_PROCESSED,
		RECORD_REJECTED,
		RECORD_EXTRACTED,
		ERR_MSG
	) VALUES (
		lv_Prog_ID,
		SYSDATE,
		lv_Scc_Count,
		lv_Err_Count,
		lv_Scc_Count-lv_Err_Count,
		lv_Err_Msg
	);

	COMMIT;
END;
/